RE:Impimir recibos xharbour
Evidentemente hay un par (si no es que es el mismo) que están tratando de cachondearse con nosotros, que estamos tratando de trabajar, con no hacerle caso es mas que suficiente:
He aqui las solución a tus probelmas:
xHarbour tiene un objeto "impresora grafica" que te permite imprimir en cualquier impresora que esté dada de alta en tu Windows usando fonts, primitvas de dibujo, etc., sin importar que tu aplicacion sea para modo consola MS-DOS, eso si tu programa tiene que ser 32 bits, este es el ejemplo:
PROCEDURE Main
LOCAL cPrinter := "EPSON Stylus DX5000 Series"
LOCAL oPrinter
LOCAL aFonts, cFont, nFont
// Crear el objeto impresora y configurar el trabajo de impresion:
oPrinter := Win32Prn():new( cPrinter )
oPrinter:landscape := .F.
oPrinter:formType := DMPAPER_A4
oPrinter:copies := 1
// Crear area para generar el informe
IF .NOT. oPrinter:create()
Alert( "No puedo crear informe" )
QUIT
ENDIF
// Crear trabajo de impresion
IF .NOT. oPrinter:startDoc( "Prueba informes xHarbour" )
Alert( "No es posible crear trabajo de impresion" )
QUIT
ENDIF
// Imprimir usando un solo font
oPrinter:textOut( "Texto con el font por omision" )
oPrinter:bold( FW_EXTRABOLD )
oPrinter:textOut( oPrinter:fontName )
oPrinter:bold( FW_NORMAL )
oPrinter:newLine()
aFonts := oPrinter:getFonts()
nFont := AScan( aFonts, ;
{|a| "ARIAL" $ Upper(a[1]) } )
cFont := aFonts[nFont,1]
// Texto en fonts proporcionales
oPrinter:setFont( cFont )
oPrinter:textOut( "Texto en font Aria" )
oPrinter:bold( FW_EXTRABOLD )
oPrinter:textOut( oPrinter:fontName )
oPrinter:bold( FW_NORMAL )
oPrinter:newLine()
// Texto a colores
oPrinter:setColor( RGB_YELLOW, RGB_BLUE )
oPrinter:textOut( "Amarrillo fondo Azul" )
oPrinter:newLine()
// Dibujar una linea de color
oPrinter:setPen( PS_DASH, 5, RGB_GREEN )
oPrinter:line( oPrinter:posX, ;
oPrinter:posY, ;
oPrinter:rightMargin, ;
oPrinter:posY )
// Enviarlo a la impresora:
oPrinter:endDoc()
// Liberar el trabajo de impresion
oPrinter:destroy()
RETURN
Para compilar tu programa a 32 bits, solo necesitas xEdit:
http://objetopersistente.blogspot.com/2008/05/de-clipper-x-harbour-con-xedit.html