Proceso Comodines
//solicitamos ingresar una cadena de texto.
Escribir "INGRESE UNA CADENA";
//leemos y guardamos la cadena en la variable cadena.
Leer cadena;
//inicializamos la cadena de comodines con los comodines.
cadena_comodines = "^$?~#@|[]()\";
//creamos un contador para saber el largo del vector con los comodines que crearemos.
contador <- 0;
//creamos 2 ciclos para comparar cada caracter de la cadena ingresada con cada caracter de
//la cadena de comodines, si son iguales, le agrega 1 al contador.
Para i<-1 Hasta Longitud(cadena) Con Paso 1 Hacer
s1 <- Subcadena(cadena,i,i);
Para j<-1 Hasta Longitud(cadena_comodines) Con Paso 1 Hacer
s2 <- Subcadena(cadena_comodines,j,j);
Si s1 = s2 Entonces
contador <- contador + 1;
Fin Si
Fin Para
Fin Para
//creamos un vector o dimension con el largo del contador.
Dimension vector_comodines(contador);
//reseteamos el contador, pero esta vez en 1 para que sea un indice para llenar el vector comodines.
contador <- 1;
//creamos de nuevos dos ciclos, esta vez para llenar el vector con los datos.
//si son iguales, ademas de llenar la matriz le suma 1 al contador.
Para i<-1 Hasta Longitud(cadena) Con Paso 1 Hacer
s1 <- Subcadena(cadena,i,i);
Para j<-1 Hasta Longitud(cadena_comodines) Con Paso 1 Hacer
s2 <- Subcadena(cadena_comodines,j,j);
Si s1 = s2 Entonces
vector_comodines(contador)<-s2;
contador <- contador + 1;
Fin Si
Fin Para
Fin Para
//hacemos un ciclo para mostrar cada elemento del vector comodines.
//(desde 1 hasta la longitud del vector comodines).
// se le resta 1 al contador por que como se inicio en 1 le va a sobrar 1.
Para i<-1 Hasta contador-1 Con Paso 1 Hacer
Escribir "COMODIN ",i,": ",vector_comodines(i);
Fin Para
//SUERTE!!!
FinProceso
